// @title hw3-exampleScore.ck
// @author Chris Chafe (cc@ccrma), Hongchan Choi (hongchan@ccrma) 
// @desc An example score file for homework 3, Music220a-2012
// @version chuck-1.3.1.3 / ma-0.2.2c
// @revision 1
//modified by Matt Halper


// pick a physical model synth, send to left chan (0)
Brass physmod => dac.left;

// bring in a mono .wav file from which to play sample
// pass through Envelope to avoid clicks from SndBuf 
// to right chan (1)
SndBuf sampler => Envelope samplerEnv => dac.right;
"/Matt Academics/Fall Quarter 2/Music 220a/HW3/hw3-starter/sample.wav" => string _file;
//me.sourceDir() + "/sample.wav" => string _file;
_file => sampler.read;
cherr <= "[score] SndBuf: " <= _file <= IO.newline();
10::ms => samplerEnv.duration;

// write signals to files
dac.left => WvOut physmodOut => blackhole;
dac.right => WvOut samplerOut => blackhole;
me.sourceDir() + "/phys.wav" => string _captureP;
//me.sourceDir() + "/Matt Academics/Fall Quarter 2/Music 220a/HW3/This_Plane_-_Acapella.L.wav" => string _captureP;
me.sourceDir() + "/samp.wav" => string _captureS;
_captureP => physmodOut.wavFilename;
_captureS => samplerOut.wavFilename;


// ------------------------------------------------------------
// three algorithms which generate numbers in range -1.0 to 1.0
// see 1) logisticMapNotes.ck 2) logisticMapNotesOSC.ck for
// more info
fun float logistic(float x, float r) {
	return r * x * (1.0 - x);
}

// see 1) psuedoRandomNotes.ck 2) psuedoRandomNotesOSC.ck for
// more info
fun float random(float r) {
    if (r > 1.0) {
        1.0 => r;
    }
    // get a random value
	return Math.random2f(-r, r);
}

// see 1) sinNotes.ck 2) sinNotesOSC.ck
fun float sinusoid(float  r) {
    // rate in radians at 1 sec period
    2 * pi => float sinScale;
    // convert to desired rate in radians
    if (r > 0.0) r /=> sinScale;
    // current time in seconds
    now / second => float nowInSeconds;
    // convert to phase angle using rate in radians
    nowInSeconds * sinScale => float currentPhase; 
    // or could be another trig function
    return Math.sin(currentPhase); 
}
// ------------------------------------------------------------


// tick the chosen algorithm to get a new value
fun float algorithm(float state, string type, float r) {
    if (type == "logistic") {
        // choose me to iterate the map and hear logistic map "tune"
        return logistic(state, r);
    } else if (type == "random") {
        // choose me for random "tune"
        return random(r);
    } else if (type == "sinusoid") {
        // choose me for sin function "tune"
        return sinusoid(r);
    } else {
        cherr <= "[score] Unknown algorithm type.\n";
    }
}

// sporkable function that plays physical model notes forever
fun void pLoop(string type, float r) {
    0.1 => float state;
    while (true) {
        // note off in case it's already on
        physmod.stopBlowing(1.0);
        // a short rest
        50::ms => now;							
        algorithm(state, type, r) => state;
        // use state as a frequency   
        440.0 + (state * 120.0)  => float f;  
        // to clarinet
        physmod.freq(f);
        // note on
        physmod.startBlowing(0.5);  

        //Brass.slide(float f, 0.5);             
        // OPTIONAL --------------------------------------
        // add any other Clarinet parameters
        //.reed - reed stiffness [0.0 - 1.0]
        // .noiseGain - noise component gain [0.0 - 1.0]
        // .clear - clear instrument
        // .vibratoFreq - vibrato frequency(Hz)
        // .vibratoGain - vibrato gain [0.0 - 1.0]
        // .pressure - pressure/volume [0.0 - 1.0]
        // .rate - rate of attack (sec)
        100::ms => now;
    }
}

// sporkable function that plays sampler notes forever
fun void sLoop(string type, float r) {
    0.1 => float state;
    while (true) {
        // turn off envelope in case it's already on
        samplerEnv.target(0.0);
        // a short rest 
        50::ms => now;							
        algorithm(state, type, r) => state;
        sampler.length() => dur totalFile;
        // time in file to start playing sample from
        ((state + 1.0) * 0.5) * totalFile => dur start;
        // sample duration
        100::ms => dur duration;
        // end time of sample
        start + duration => dur end;
        if (end > totalFile) {
            end - duration => start;
        }
        // start position in file in actual samples
        sampler.pos((start / samp) $ int);
        // ramp up the envelope
        samplerEnv.target(1.0);
        
        // OPTIONAL ----------------------------------------
        // play around with 
        // .rate - (float, READ/WRITE) set/get playback rate 
        //         relative to file's natural speed. Try the
        //         range between [-1, 1] and experiment.
        duration => now;
    }
}


// ------------------------------------------------------------
// prepare the show
Shred pShred;
Shred sShred;

// needed to stop both shreds gracefully
fun void killShreds() {
    pShred.exit();
    sShred.exit();
    me.yield();
    // note off
    physmod.stopBlowing(1.0);
    // turn off envelope
    samplerEnv.target(0.0);		
    10::ms => now;
}


// ------------------------------------------------------------
// start the show
spork ~pLoop("logistic", 3) @=> pShred; // clarinet played by logistic map frequencies

10::second => now;
killShreds();

spork ~sLoop("random", 0.5) @=> sShred; // samples pulled randomly	
10::second => now;
killShreds();

spork ~pLoop("logistic", 1) @=> pShred; // clarinet played by logistic map frequencies
spork ~sLoop("random", 0.5) @=> sShred; // samples pulled randomly	
10::second => now;
killShreds();


int counter;
for (0 => int i; i < 4; ++i) {
    spork ~pLoop("sinusoid", 5.0 + counter) @=> pShred;
    spork ~sLoop("sinusoid", 5.0) @=> sShred;
    5::second => now;
    counter++;
}

// ------------------------------------------------------------
// finish the show
physmodOut.closeFile();
samplerOut.closeFile();

// print message in terminal for sox command
cherr <= "[score] Finished. Merge two products with the command below.\n";
cherr <= "sox -M " <= _captureP <= " " <= _captureS <= " ";
cherr <= me.sourceDir() + "/Milestone.wav";