class BubblePluckVoice extends VoiceBankVoice
{
    // override
    0.5 => gainAtZeroVelocity;
    0.8 => highCutoffSensitivity;
    -0.3 => lowCutoffSensitivity;
    
    1 => int unison;

    400 => float myLPFCutoff;
    1 => float myFreqModifier;
    LPF lpf => adsr;
    
    SqrOsc osc1[unison];
    SawOsc osc2[unison];
    SqrOsc osc3[unison];
    
    // oscs, gain, widths
    for( int i; i < unison; i++ )
    {
        0.56 / unison => osc1[i].gain;
        0.18 / unison => osc2[i].gain;
        0.26 / unison => osc3[i].gain;
        osc1[i] => lpf;
        osc2[i] => lpf;
        osc3[i] => lpf;
    }
    
    
    fun void sync()
    {
        for( int i; i < unison; i++ )
        {
            0 => osc1[i].phase => osc2[i].phase => osc3[i].phase;
        }
    }
    
    
    Envelope pitchEnv => blackhole;
    fun void PitchEnv()
    {
        6::ms => pitchEnv.duration;
        0 => pitchEnv.value;
        1 => pitchEnv.target;
        now + pitchEnv.duration() => time end;
        while( now < end )
        {
            Std.scalef( Math.pow( pitchEnv.value(), 4 ), 0, 1, 1, 4 ) => myFreqModifier;
            0.1::ms => now;
        }
        1 => myFreqModifier;
    }
    
    
    // cubic scale
    fun float cutoffToHz( float cutoff )
    {
        return Math.min( Std.scalef( Math.pow( Std.clampf( cutoff, 0, 1 ), 3 ), 0, 1, myFreq, 18000 ), 18000);
    }
    
    // LPF cutoff envelope
    ADSR lpfEnv => blackhole;
    0.349 => float lpfSustain;
    240::ms => dur lpfDecay;
    lpfEnv.set( 1::ms, lpfDecay, lpfSustain, 7700::ms );
    
    fun void triggerLPFEnv()
    {
        // reset
        0 => lpfEnv.value;
        lpfSustain => lpfEnv.sustainLevel;
        // bounds
        Math.pow( myVelocity, 1.6 ) => float v;
        Std.scalef( v, 0, 1, 0.05, 0.24 ) => float minCutoff;
        // higher cutoff at higher velocity
        Std.scalef( v, 0, 1, 0.3, 1.0 ) => float maxCutoff;
        
        minCutoff => float currentCutoff;
        maxCutoff - minCutoff => float cutoffDiff;
                
        lpfEnv.keyOn( 1 );
        
        5::ms => dur delta;
                        
        while( true )
        {
            // set
            minCutoff + cutoffDiff * Math.pow( lpfEnv.value(), 3 ) => currentCutoff;
            // Math.pow( currentCutoff, 3 ) => currentCutoff;
            currentCutoff + myCutoff => this.cutoffToHz => myLPFCutoff;
                                    
            // wait
            delta => now;
        }        
    }
    spork ~ this.triggerLPFEnv() @=> Shred triggerLPFEnvShred;
    
    fun void endLPFEnv()
    {
        lpfEnv.keyOff( 1 );
    }
    

    
    // resonances
    1.0 => lpf.Q;
    
    // then ADSR on volume
    330::ms => rTime;
    adsr.set( 1::ms, 100::ms, 0.995, rTime );
    
    // osc1: freq
    // osc2: +3
    // osc3: -3
    fun void applyFreqs()
    {
        float f1, f2, f3;
        while( true )
        {
            Math.min( myLPFCutoff, 21000 ) => lpf.freq;
            
            // myFreq
            myFreq * myFreqModifier => f1;
            // +3c
            f1 * 1.001734 => f2;
            // -3c
            f1 * 0.998269 => f3;
            
            for( int i; i < unison; i++ )
            {
                f1 => osc1[i].freq;
                f2 => osc2[i].freq;
                f3 => osc3[i].freq;
            }
            
            0.5::ms => now;
        }
    }
    spork ~ this.applyFreqs();
    
    // trigger note on
    fun void noteOn()
    {
        // key on
        adsr.keyOn( 1 );
        triggerLPFEnvShred.exit();
        spork ~ this.triggerLPFEnv() @=> triggerLPFEnvShred;
        sync();
        spork ~ PitchEnv();
    }
    
    // trigger note off
    fun void noteOff()
    {
        adsr.keyOff( 1 );
        endLPFEnv();
    }
    
}


class BubblePluck extends VoiceBank
{
    8 => numVoices;
    
    // voices
    BubblePluckVoice myVoices[numVoices];
    // assign to superclass
    v.size( myVoices.size() );
    for( int i; i < myVoices.size(); i++ )
    {
        myVoices[i] @=> v[i];
    }
    // connect
    init( true );    
}

BubblePluck b => LPF l => JCRev rev => dac;
0.3 => b.gain;
0.0 => rev.mix;
15000 => l.freq;

// knobs
global float gReverb;
global float gCutoff;
global float gLowpass;

fun void ApplyGlobals()
{
    while( true )
    {
        10::ms => now;
        gReverb => rev.mix;
        gLowpass => l.freq;
        gCutoff => b.cutoff;
    }
}
spork ~ ApplyGlobals();

// end knobs


global Event midiMessage;
global int midiCommand;
global int midiNote;
global int midiVelocity;

fun void NoteOn( int m, int v )
{
    v * 1.0 / 128 => float velocity;
    b.noteOn( m, velocity );
    //<<< "on", m, v >>>;
}


fun void NoteOff( int m )
{
    spork ~ b.noteOff( m );
    //<<< "off", m >>>;
}


while( true )
{
    midiMessage => now;
    if( midiCommand >= 144 && midiCommand < 160 )
    {
        if( midiVelocity > 0 )
        {
            NoteOn( midiNote, midiVelocity );
        }
        else
        {
            NoteOff( midiNote );
        }
    }
    else if( midiCommand >= 128 && midiCommand < 144 )
    {
        NoteOff( midiNote );
    }
    else
    {
        //<<< "unknown midi command:", midiCommand, midiNote, midiVelocity >>>;
    }
}