///INITIALIZE DECKS---------------------------------------------------------------------------------------------------------

//Path...
"C:/Users/Public/Documents/School/220C/" => string path;

//Prepare deck
SndBuf deck => dac;
path + "SoleSide.wav" => deck.read;
0.0 => deck.rate;

///INITIALIZE CONTROLLER--------------------------------------------------------------------------------------------------

//Window size
2::ms => dur window;

//Device Setup
0 => int device;
Hid tt;
HidMsg ttdata;

// try
if( !tt.openMouse( device ) ) me.exit();
<<< "mouse '" + tt.name() + "' ready...", "" >>>;

///nnnnnnnnGOOOOO!----------------------------------------------------------------------------------------------------------

//data
10.0 => float CtrlRate;
0.0 => float ttrate;

//Setup envelope
Envelope env => blackhole;
window => env.duration;
0.0 => env.value;


//andGO!!!
spork~ envRead();
analyze();

///Helpers-----------------------------------------------------------------------------------------------------------------------

fun void envRead() {
    while(true) {
        env.value() => deck.rate;
        1::samp => now;
    }
}

//use mouse-speed to determine playback speed
fun void analyze() {
    
    while(true) {
        tt => now;
        while(tt.recv( ttdata )) {
             if(ttdata.isMouseMotion()) {
                if(ttdata.deltaX >= -1 && ttdata.deltaX <= 1 ) 1.0 => ttrate;
                else  ttdata.deltaX / CtrlRate => ttrate;
            }
            ttrate => env.target;
        }
    }  
}