// @title m220a-Player.ck
// @desc a sample sound player goes with DataReader class
// @author Chris Chafe (cc@ccrma)

//=== TODO: modify this path and name for your system ===//
"/Users/briangurewitz/Desktop/Sleep/" => string dataDir;
"eeg_fpzcz_sleep.dat" => string dataFile;


dac => WvOut2 out => blackhole;
me.sourceDir() + "/eeg_fpzoz_sleep.wav" => string _capture;
_capture => out.wavFilename;



// update rate in ms
10.0 => float update; 

// new class to manage envelopes
class Env
{
  Step s => Envelope e => blackhole; // feed constant into env
  update::ms => e.duration; // set ramp time
  fun void target (float val) { e.target(val); }
}

class Player
{
  SinOsc s => NRev rev => dac;
  rev.mix(0.02);
  Env amp, freq;
  fun void run() // sample loop to smoothly update gain
  { 
    while (true)
    {
      s.gain(amp.e.last());
      s.freq(freq.e.last());
      1::samp => now;
    }
  }  spork ~ run(); // run run
}

DataReader eeg_fpzcz;
eeg_fpzcz.setDataSource(dataDir + dataFile);
eeg_fpzcz.start(); 
Player p;
while (!eeg_fpzcz.isFinished())
{
    // next data point, scaled in 0.0 - 1.0 range
    eeg_fpzcz.scaledVal() => float w;
    p.amp.target(0.5 * Math.pow(w,1.6));
    p.freq.target(Std.mtof(20 + w*62));

    update::ms => now;
}